- 1. Introduction
- 2. Downloads
- 3. Installation
- 4. Basic Usage
- 5. Advanced Usage
- 6. Source
- 6.1. Using Source
- 6.2. Builtin Sources
- 7. Tips
- 7.1. Not to complete automatically
- 7.2. Not to show completion menu automatically
- 7.3. Stop completion
- 7.4. Finish completion by TAB
- 7.5. Select candidates with C-n/C-p only when completion menu is displayed
- 7.6. Not to use quick help
- 7.7. Change a height of completion menu
- 7.8. Enable
auto-complete-modeautomatically for specific modes
- 7.9. Ignore case
- 7.10. Stop completion automatically after inserting specific words
- 7.11. Change colors
- 7.12. Change default sources
- 7.13. Change sources for specific major modes
- 7.14. Completion with specific source
- 7.15. Show help persistently
- 7.16. Show a lastly completed candidate help
- 7.17. Show help beautifully
- 8. Configuration
- 9. Extend
- 9.1. Prototype
- 9.2. Example
- 9.3. Initialization
- 9.4. Cache
- 9.5. Action
- 9.6. Omni Completion
- 9.8. Source Properties
- 9.9. Variables
- 10. Trouble Shooting
- 11. Known Bugs
- 12. Reporting Bugs
Auto Complete Mode (aka
auto-complete-mode) is a extension that automates and advances completion-system of GNU Emacs. This is superior than old system:
- Visual interface
- Reduce overhead of completion by using statistic method
This user manual covers from how to install and how to use to how to extend. Please contact me if you have question.
You can download from Auto Complete Mode top page.
- 800MHz or higher CPU
- 256MB or higher RAM
- GNU Emacs 22 or later
3.2. Installation Script
It is easy to install by using a installation script called
etc/install.el that is located in the package directory.
M-x load-file RET in the running Emacs or newly launched Emacs. Note that if you want to upgrade
auto-complete-mode, you have to install in a newly launched Emacs with
-q option. Then input a file name to load which is a path string with adding
/etc/install.el to the package directory. For example, if the package directory is
~/tmp/auto-complete-1.2, the file name will be
Then input a directory where Auto Complete will be installed. You need to add a directory to
load-path later if
load-path doesn't include the directory. The directory is to be
~/.emacs.d by default.
RET to start installation. After installation, you may see the following buffer and follow instructions to edit
You can also install from terminal like:
$ make install $ # or with directory specified $ make install DIR=$HOME/.emacs.d/
If you don't have GNU Make, run emacs like:
$ emacs -batch -l etc/install.el
Example message after installation (*Installation Result* Buffer)
Successfully installed! Add the following code to your .emacs: (add-to-list 'load-path "~/.emacs.d") ; This may not be appeared if you have already added. (add-to-list 'ac-dictionary-directories "~/.emacs.d/ac-dict") (require 'auto-complete-config) (ac-config-default)
3.3. Manual Installation
It is also possible to install manually if you follow a directory configuration. First, do byte-compile all
.el files in the package directory. You may use
Makefile in UNIX OS.
$ make byte-compile
If you can't use
Makefile, open the directory from Emacs by
C-x d and type
* . el RET B RET to do byte-compile.
Then copy all
.el files and
.elc files to a directory which is added to
load-path. You may do such the following command if the directory is
$ cp *.el *.elc ~/.emacs.d
And then install dictionary files. They are optional to run Auto Complete Mode, but you should install if you don't have any reason. Dictionary files are located in called
dict directory, it is needed that they are installed to a directory which is
auto-complete.el has been installed. If you installed
auto-complete.el to a directory called
~/.emacs.d, you also have to install dictionary files to
~/.emacs.d. Please be careful not to overwrite existed files. It may be rare case, but the installation script above avoids overwrite by renaming
dict directory to
$ cp -r dict ~/.emacs.d
Finally add the following code to
(add-to-list 'ac-dictionary-directories "~/.emacs.d/dict") (require 'auto-complete-config) (ac-config-default)
If you haven't added the directory to
load-path, you need to add the following code too.
(add-to-list 'load-path "~/.emacs.d")
Type some characters in *scratch* buffer in a restarted Emacs or newly launched Emacs. It is successful if you see completion menu. If you have error or no completion is started, it is failure maybe. Please contact me in such case with confirmation following:
A directory which
auto-complete.elis installed to is in
If you don't see characters
ACin mode-line (a gray line of bottom of buffer),
auto-complete-modeis not enabled. Type
M-x auto-complete-modeto enable and try again.
If you have *Backtrace* with errors or errors in minibuffer (bottom of frame), please contact me with the errors.
4. Basic Usage
First, in a meaning,
auto-complete-mode has no "usage". Because
auto-complete-mode is designed to fade into Emacs editing system. Users will be received a highly-developed completion-system automatically without any difficulty. Ultimately, a goal of
auto-complete-mode is to provide a system that does what users want without any command, but it is impossible to accomplish 100% accuracy actually. So there is "usage" to cover that points.
4.1. Input Characters
Inputting characters is basic. Any completion will never be shown without any character. So when completion will be started, in other others, what character causes completion to be started? It is good question but it is difficult to answer here. In simple words, completion will be started when just character is inserted. See
ac-trigger-commands for more details.
4.2. Completion by TAB
After completion is started, completion by TAB will be enabled temporarily. Completion by TAB is the most important and most frequent used command. TAB has several meanings.
Case that only one candidate remains
If only on candidate remains, the candidate will be used to complete.
Case that there is common part among candidates
For example, if all candidates start with "set", it means they have common part "set". So TAB completes "set" at first.
Otherwise, select candidates in cycle by typing TAB.
It may be different a little according to settings, but basically completion by TAB works as we wrote above. A reason why TAB has several meanings is that we want users to do anything with TAB.
4.3. Completion by RET
Like completion by TAB but some points are different:
- Complete a selected candidate immediately
- Execute an action if a selected candidate has the action
It is necessary to type TAB a few times for completion by TAB. Completion by RET instead complete a selected candidate immediately, so when you see a candidate you want, just type RET. If the candidate has an action, the action will be executed. Take a example of builtin abbrev completion. In completion by TAB, an abbrev which expands "www" to "World Wide Web" will be completed to "www", but in completion by RET, the abbrev will be expanded to "World Wide Web" as completion.
4.4. Candidate Selection
auto-complete-mode philosophy, it is not recommended to select candidates. Because, it means it has been failed to guess completion, and also it requires for users to do candidate selection which is a high cost operation. We think there is so many cases that requires to do candidate selection, because completion by TAB will help candidate selection somehow and in recent version, a statistic method contributes to make a candidate suggestion more accurate. However, actually, this is such cases. So we also think it is not bad idea to remember how to select candidates.
Selecting candidates is not a complex operation. You can select candidates forward or backward by cursor key or
M-n. According to setting, a behavior of completion by TAB will be changed as a behavior of completion by RET. See
ac-dwim for more details.
There is other ways to select candidates.
M-1 to select candidate 1,
M-2 to select candidate 2, and so on.
auto-complete-mode has two type of help functionalities called Quick Help and Buffer Help. They are different in a point of displaying. Quick help will appear at the side of completion menu, so you can easily see that, but there is a problem if there is no space to displaying the help. Quick help will be shown automatically. To use quick help, you need to set
t. Delay time show quick help is given by
On other side, buffer help will not be shown without any instructions from users. Buffer help literally display a help in a buffer of other window. It costs much to see than quick help, but it has more readability. To show buffer help, press
f1. By pressing
C-M-S-v after showing buffer help, you can scroll forward or backward for help buffer. Other commands will be fallbacked and buffer help will be closed.
Completion will be started by inserting characters. After completion is started, operations in the following table will be enabled temporarily. After completion is finished, these operations will be disable.
|TAB, C-i||ac-expand||Completion by TAB|
|RET, C-m||ac-complete||Completion by RET|
|down, M-n||ac-next||Select next candidate|
|up, M-p||ac-previous||Select previous candidate|
|C-?, f1||ac-help||Show buffer help|
To stop completion, use
5. Advanced Usage
Basically there is assumption that
auto-complete-mode will be started automatically, but there is also exception. For example, that is a case that an user wants to complete without inserting any character or a case not to start
auto-complete-mode automatically by settings. A command called
auto-complete is useful in such cases, which is used with key binding in general. The following code changes a default completion command to more advanced feature that
(define-key ac-mode-map (kbd "M-TAB") 'auto-complete)
So, as of
auto-complete command, it is a little different from an original automatic completion.
Case that only one candidate remains
Complete immediately without showing completion menu.
Case that no candidates remains
Attempt to complete with fuzzy matching. See Completion by Fuzzy Matching for more details.
5.2. Completion by Fuzzy Matching
In a case that there is no candidates by
auto-complete command or a case that
ac-fuzzy-complete command is executed,
auto-complete-mode attempts to complete with fuzzy matching instead of usual exact matching. Parameters of fuzzy matching has already been optimized for use, so users don't need to change them. However if you want to know the internals, see
fuzzy.el. Using completion by fuzzy matching, typo will be fixed as a series of completion. For instance, input "messaeg" in a buffer, and then do
M-x auto-complete or
M-x ac-fuzzy-complete. The cursor color will be changed to red if completion has been successful, and then you can continue to complete with regarding of "messaeg" as "message". It is not bad idea to bind
auto-complete command to some key in a meaning of handling such cases.
5.3. Filtering Completion Candidates
You can start filtering by
C-s. The cursor color will be changed to blue. Then input characters to filter. It is possible to do completion by TAB or select candidates, which changes the cursor color to original so that telling filtering completion candidates has done. The filtering string will be restored when
C-s again. To delete the filter string, press
C-h. Other general operations is not allowed there.
5.4. Trigger Key
It is difficult what key
auto-complete command is bound to. It should be bound to a key which is easy to press as much as possible because completion operation is often happened. However, it is a major problem that there is no empty key to press easily.
auto-complete-mode provides a feature called Trigger Key that handles such the problem. Using trigger key, you can use an arbitrary key temporarily if necessary. The following code uses
TAB as trigger key.
Trigger key will be enabled after inserting characters. Otherwise it is dealt as an usual command (TAB will be indent). Generally, trigger key is used with
(setq ac-auto-start nil)
5.5. Candidate Suggestion
auto-complete-mode analyzes completion operations one by one and reduces overheads of completion as much as possible. For example, having a candidate "foobar" been completed few times,
auto-complete-mode arranges it to top of the candidates next time and make a situation that allows users to complete the word with one time TAB or few times TAB. It is called
comphist internally, and you can use it by setting
t. It is enabled by default. Collection operations data will be stored in
~/.emacs.d/ with a name
auto-complete-mode collects two types of data to accomplish accurate candidate suggestion.
- Count of completion
- Position of completion
Simply saying, it collects not only a completion count but also a position of completion. A completion candidate will be scored with the count and the point. If you complete
find-file with a word f few times, in next time
find-file will be arranged to top of candidates. However it is too simple. Actually
find- will not have the same score, because a distance between
find- will reduce a weight of scoring. It means that if you often complete
find-library will get high score than
find-file at that position. So
auto-complete-mode can guess
find-file will be top after
find-library will be top after
find- as it seems to learn from users' operations.
5.6. Completion by Dictionary
Dictionary is a simple list of string. There is three types of dictionary: user defined dictionary, major mode dictionary, and extension dictionary. You need to add
ac-sources (default). See source for more details.
5.6.1. User Defined Dictionary
User defined dictionary is composed of a list of string specified
ac-user-dictionary and dictionary files specified by
ac-user-dictionary-files. Dictionary file is a word list separated with newline. User defined dictionary is shared with all buffers. Here is example adding your mail address to dictionary.
(add-to-list 'ac-user-dictionary "firstname.lastname@example.org")
Setting will be applied immediately. Try to input "foo" in a buffer. You may see
email@example.com as a completion candidate. This setting will be cleared if Emacs will quit. You need to write the following code to keep setting in next Emacs launching.
(setq ac-user-dictionary '("firstname.lastname@example.org" "email@example.com"))
There is more easy way to add word to dictionary. Files specified by
ac-user-dictionary-files will be treated as dictionary files. By default,
~/.dict will be a dictionary file, so edit
As we said, words are separated with newline. They are not applied immediately, because
auto-complete-mode uses cache not to load every time from a dictionary file. It may be high cost. To clear cache, do
M-x ac-clear-dictionary-cache. After that, dictionary files will be load absolutely.
No need to say perhaps, you can use other files as dictionary file by adding to
5.6.2. Major Mode Dictionary and Extension Dictionary
You can use other dictionaries for every major-modes and extensions. A dictionary will loaded from a directory specified with
ac-dictionary-directories may be the following setting if you followed installation instructions.
(add-to-list 'ac-dictionary-directories "~/.emacs.d/ac-dict")
A dictionary named
c++-mode for specific major-mode and a dictionary named
txt for specific extension will be stored in the directory. For instance, you complete in a buffer named
a.cpp with dictionary completion, following the setting above,
~/.emacs.d/ac-dict/cpp will be loaded as dictionary file. You can edit the dictionary files and make a new one. In addition, you can add a new dictionary file to a directory that has same configuration.
As same as user defined dictionary, after editing and adding dictionary, you should do
M-x ac-clear-dictionary-cache to apply changes.
Source is a concept that insures a extensibility of
auto-complete-mode. Simply saying, source is a description about:
- How to generate completion candidates
- How to complete
- How to show
Anybody who know about Emacs Lisp a little can define a source easily. See extend for how to define a source. Here we can explain how to use builtin sources.
Usually a name of source starts with
ac-source-. So you can list up sources with
M-x apropos RET ^ac-source-). You may see
ac-source-dictionary which are entities of sources.
6.1. Using Source
If you wrote
(ac-config-default) in your
.emacs, it is rare to change a source setting because it is already optimized to use. Here is a short explanation about source however. Sources will be used by setting
ac-sources to a list of sources. You can see the setting by evaluating
ac-sources in *scratch* buffer:
;; Formatted (ac-source-filename ac-source-functions ac-source-yasnippet ac-source-variables ac-source-symbols ac-source-features ac-source-abbrev ac-source-words-in-same-mode-buffers ac-source-dictionary)
As you see,
ac-sources in *scratch* buffer has six sources. We explain each source for detail, you can guess meanings of sources. It is worth to remember that
ac-sources is a buffer local variable, which means each
ac-sources for buffers will be different.
Here is an example. Think you are at *scratch* buffer. As we said, this buffer has many sources. Some people think it is too many. So try to change
ac-sources to reduce functionalities. It is easy to change. Just evaluate the following code in *scratch* buffer or with
(setq ac-sources '(ac-source-symbols ac-source-words-in-same-mode-buffers))
This example changes
ac-source setting and enable only symbol completion and word completion among same major modes. Then, how can we enable this setting in next Emacs launching? We can change settings by adding a hook which is called when *scratch* buffer is created.
(defun my-ac-emacs-lisp-mode () (setq ac-sources '(ac-source-symbols ac-source-words-in-same-mode-buffers))) (add-hook 'emacs-lisp-mode-hook 'my-ac-emacs-lisp-mode)
If a code
(ac-config-default) is written in
.emacs, the code above may not be worked correctly. It is because of
(ac-config-default) will overwrite the setting. In such case, you can redefine a function which is used in
(ac-config-default). The function name is
auto-complete-config.el for more details.
(defun ac-emacs-lisp-mode-setup () (setq ac-sources '(ac-source-symbols ac-source-words-in-same-mode-buffers)))
So, now you know how to change sources in a specific major mode. Summary is:
- Define a function changing
- Register the function to proper mode hooks (
By the way, how can we change a setting for all buffers? We use
setq-default to change
ac-sources instead of
setq in such case. Then the default value of
ac-sources will be changed to the value you specified.
(setq-default ac-sources '(ac-source-words-in-all-buffer))
There is other ways to do that.
(ac-config-default) changes the default value of
ac-sources by registering a hook for
auto-complete-mode. The registered function is
ac-common-setup that adds
ac-source-filename to the first of
ac-sources by default. So all
auto-complete-mode enabled buffer will have
ac-source-filename at the first of
ac-sources. A reason why adding to the first is relating to omni completion. Anyway you don't care about it here. So if you want to change
ac-sources of all buffer, you can redefine
ac-common-setup function to do that.
;; Add ac-source-dictionary to ac-sources of all buffer (defun ac-common-setup () (setq ac-sources (append ac-sources '(ac-source-dictionary))))
6.2. Builtin Sources
Here are defined sources in
A source for Emacs abbreviation function. See
info emacs Abbrevs about abbreviation function.
A source for CSS property.
A source for dictionary. See completion by dictionary about dictionary.
A source for Emacs-eclim.
A source for completing features which are available with
A source for completing file name. Completion will be started after inserting
A source for completing files in a current directory. It may be useful with
A source for completing Emacs Lisp functions. It is available only after
A source for completing tags of Global.
A source for completing
imenu nodes. See
info emacs imenu for details.
A source for Semantic. It can be used for completing member name for C/C++.
ac-source-semantic, this source is for completing symbols in a raw namespace.
A source for completing Emacs Lisp symbols.
A source for completing Emacs Lisp symbols.
A source for completing words in all buffer. Unlikely
ac-source-words-in-same-mode-buffers, it doesn't regard major-mode.
A source for completing words in a current buffer.
A source for completing words which are collected over buffers whom major-mode is same to of a current buffer. For example, words will shared among
b.cpp, but not shared among
b.cpp because they are different major-mode buffers. Usually this source is more useful than
A source for Yasnippet to complete and expand snippets.
7.1. Not to complete automatically
If you are being annoyed with displaying completion menu, you can disable automatic starting completion by setting
(setq ac-auto-start nil)
You need to bind some key to
auto-complete command (because you need to complete anyway). For example, bind to
ac-mode-map, which is a key map for
auto-complete-mode enabled buffer:
(define-key ac-mode-map (kbd "M-TAB") 'auto-complete)
Or bind to global key map.
(global-set-key "\M-/" 'auto-complete)
In addition, if you allow to start completion automatically but also want to be silent as much as possible, you can do it by setting
ac-auto-start to an prefix length integer. For example, if you want to start completion automatically when you has inserted 4 or more characters, just set
ac-auto-start to 4:
(setq ac-auto-start 4)
ac-auto-start to large number will result in good for performance. Lesser
ac-auto-start, more high cost to produce completion candidates, because there will be so many candidates necessarily. If you feel
auto-complete-mode is stalling, change
ac-auto-start to a larger number or
ac-auto-start for more details.
And consider to use trigger key.
7.2. Not to show completion menu automatically
There is another approach to solve the annoying problem is that not to show completion menu automatically. Not to show completion menu automatically, set
(setq ac-auto-show-menu nil)
When you select or filter candidates, completion menu will be shown.
In other way, you can delay showing completion menu by setting
ac-auto-show-menu to seconds in real number.
;; Show 0.8 second later (setq ac-auto-show-menu 0.8)
This interface has both good points of completely automatic completion and completely non-automatic completion. This may be default in the future.
7.3. Stop completion
You can stop completion by pressing
C-g. However you won't press
C-g while defining a macro. In such case, it is a good idea to bind some key to
(define-key ac-completing-map "\M-/" 'ac-stop)
Now you can stop completion by pressing
7.4. Finish completion by TAB
As we described above, there is many behaviors in TAB. You need to use TAB and RET properly, but there is a simple interface that bind RET to original and TAB to finish completion:
(define-key ac-completing-map "\t" 'ac-complete) (define-key ac-completing-map "\r" nil)
7.5. Select candidates with C-n/C-p only when completion menu is displayed
By evaluating the following code, you can select candidates with C-n/C-p, but it might be annoying sometimes.
;; Bad config (define-key ac-completing-map "\C-n" 'ac-next) (define-key ac-completing-map "\C-p" 'ac-previous)
In this case, it is better that selecting candidates is enabled only when completion menu is displayed so that the key input will not be taken as much as possible.
ac-menu-map is a keymap for completion on completion menu which is enabled when
(setq ac-use-menu-map t) ;; Default settings (define-key ac-menu-map "\C-n" 'ac-next) (define-key ac-menu-map "\C-p" 'ac-previous)
7.6. Not to use quick help
A tooltip help that is shown when completing is called quick help. You can disable it if you don't want to use it:
(setq ac-use-quick-help nil)
7.7. Change a height of completion menu
ac-menu-height to number of lines.
;; 20 lines (setq ac-menu-height 20)
auto-complete-mode automatically for specific modes
auto-complete-mode won't be enabled automatically for modes that are not in
ac-modes. So you need to set if necessary:
(add-to-list 'ac-modes 'brandnew-mode)
7.9. Ignore case
There is three ways to distinguish upper case and lower case.
;; Just ignore case (setq ac-ignore-case t) ;; Ignore case if completion target string doesn't include upper characters (setq ac-ignore-case 'smart) ;; Distinguish case (setq ac-ignore-case nil)
7.10. Stop completion automatically after inserting specific words
ac-ignores to words that stops completion automatically. In ruby, some people want to stop completion automatically after inserting "end":
(add-hook 'ruby-mode-hook (lambda () (make-local-variable 'ac-ignores) (add-to-list 'ac-ignores "end")))
ac-ignores is not a buffer local variable, so you need to make it buffer local with
make-local-variable if it is buffer specific setting.
7.11. Change colors
Colors settings are following:
||Foreground color of inline completion|
||Color of completion menu|
||Selection color of completion menu|
To change face background color, use
set-face-background. To change face foreground color, use
set-face-foreground. To set underline, use
;; Examples (set-face-background 'ac-candidate-face "lightgray") (set-face-underline 'ac-candidate-face "darkgray") (set-face-background 'ac-selection-face "steelblue")
7.12. Change default sources
Read source first if you don't familiar with sources. To change default of sources, use
(setq-default ac-sources '(ac-source-words-in-all-buffer))
7.13. Change sources for specific major modes
For example, you may want to use specific sources for C++ buffers. To do that, register a hook by
add-hook and change
(add-hook 'c++-mode (lambda () (add-to-list 'ac-sources 'ac-source-semantic)))
7.14. Completion with specific source
You can start completion with specific source. For example, if you want to complete file name, do
M-x ac-complete-filename at point. Or if you want to complete C/C++ member name, do
M-x ac-complete-semantic at point. Usually, you may bind them to some key like:
;; Complete member name by C-c . for C++ mode. (add-hook 'c++-mode-hook (lambda () (local-set-key (kbd "C-c .") 'ac-complete-semantic))) ;; Complete file name by C-c / (global-set-key (kbd "C-c /") 'ac-complete-filename)
Generally, such commands will be automatically available when sources are defined. Assume that a source named
ac-source-foobar is being defined for example, a command called
ac-complete-foobar will be also defined automatically. See also builtin sources for available commands.
If you want to use multiple sources for a command, you need to define a command for it like:
(defun semantic-and-gtags-complete () (interactive) (auto-complete '(ac-source-semantic ac-source-gtags)))
auto-complete function can take an alternative of
7.15. Show help persistently
ac-persist-help instead of
ac-help, which is bound to
7.16. Show a lastly completed candidate help
ac-last-help command shows a lastly completed candidate help in a
ac-help (buffer help) form. If you give an argument by
C-u or just call
ac-last-persist-help, its help buffer will not disappear automatically.
ac-last-quick-help command show a lastly completed candidate help in a
ac-quick-help (quick help) form. It is useful if you want to see a function documentation, for example.
You may bind keys to these command like:
(define-key ac-mode-map (kbd "C-c h") 'ac-last-quick-help) (define-key ac-mode-map (kbd "C-c H") 'ac-last-help)
7.17. Show help beautifully
If pos-tip.el is installed,
auto-complete-mode uses its native rendering engine for displaying quick help instead of legacy one.
Any configuration item will be set in
.emacs or with
M-x customize-group RET auto-complete RET.
Delay time to start completion in real number seconds. It is a trade off of responsibility and performance.
Show completion menu automatically if
t means always automatically showing completion menu.
nil means never showing completion menu. Real number means delay time in seconds.
Whether or not to show completion menu immediately on
auto-complete command. If inline completion has already been showed, this configuration will be ignored.
Whether or not to expand a common part of whole candidates.
Specify a list of face symbols for disabling auto completion. Auto completion will not be started if a face text property at a point is included in the list.
Whether or not to stop Flymake on completion.
Whether or not to use fuzzy matching.
Change cursor color to specified color when fuzzy matching is started.
nil means never changed. Available colors can be seen with
Whether or not to use candidate suggestion.
nil means never using it and get performance better maybe.
Specify a percentage of limiting lower scored candidates. 100% for whole scores.
Specify a file stores data of candidate suggestion.
Whether or not to use quick help.
Delay time to show quick help in real number seconds.
Specify an integer of lines of completion menu.
Specify an integer of lines of quick help.
Limit a number of candidates. Specifying an integer, the value will be a limit of candidates.
nil means no limit.
Specify major modes as a list of symbols that will be enabled automatically if
global-auto-complete-mode is enabled.
Specify a regexp that identifies starting completion or not for that package.
Specify commands as a list of symbols that starts completion automatically.
self-insert-command is one of default.
ac-trigger-commands expect this will be used on completing.
Specify a trigger key.
Specify how completion will be started.
t means always starting completion automatically.
nil means never started automatically. An integer means completion will not be started until the value is more than a length of the completion target string.
Specify a list of strings that stops completion.
Specify how distinguish case.
t means always ignoring case.
nil means never ignoring case.
smart in symbol means ignoring case only when the completion target string doesn't include upper characters.
"Do What I Mean" function.
- After selecting candidates, TAB will behave as RET
- TAB will behave as RET only on candidate remains
Specify a special keymap (
ac-menu-map) should be enabled when completion menu is displayed.
ac-menu-map will be enabled when it is
t and satisfy one of the following conditions:
nil, and completion menu is displayed after starting completion
- Completion menu is displayed by
- Completion menu is displayed by
Use only when operations is not affected. Internally it uses
overriding-local-map, which is too powerful to use with keeping orthogonality. So don't use as much as possible.
Face of inline completion.
Face of completion menu background.
Face of completion menu selection.
Whether or not to use
auto-complete-mode globally. It is
t in general.
Specify a dictionary as a list of string for completion by dictionary.
Specify a dictionary files as a list of string for completion by dictionary.
Specify a dictionary directories as a list of string for completion by dictionary.
Specify sources as a list of source. This is a buffer local variable.
Keymap for completion.
Keymap for completion on completion menu. See also
auto-complete-mode enabled buffers.
A meaning to extend
auto-complete-mode is just defining a source. This section describe how to define a source.
Source basically takes a form of the following:
(defvar ac-source-mysource1 '((prop . value) ...))
As you see, source is just an associate list. You can define a source by combining pairs of defined property and its value.
The most important property for source is
candidates property. This property describes how to generate completion candidates by giving a function, an expression, or a variable. A result of evaluation should be a list of strings. Here is an example to generate candidates "Foo", "Bar", and "Baz":
(defvar ac-source-mysource1 '((candidates . (list "Foo" "Bar" "Baz"))))
Then add this source to
ac-sources and use:
(setq ac-sources '(ac-source-mysource1))
It is successful if you have "Bar" and "Baz" by inserting "B". The example above has an expression
(list ...) in
candidates property. The expression specified there will not be byte-compiled, so you should not use an expression unless it is too simple, because it has a bad affection on performance. You should use a function instead maybe:
(defun mysource1-candidates () '("Foo" "Bar" "Baz")) (defvar ac-source-mysource1 '((candidates . mysource1-candidates)))
The function specified in
candidates property will be called without any arguments on every time candidates updated. There is another way: a variable.
You may want to initialize a source at first time to complete. Use
init property in these cases. As same as
candidates property, specify a function without any parameters or an expression. Here is an example:
(defvar mysource2-cache nil) (defun mysource2-init () (setq mysource2-cache '("Huge" "Processing" "Is" "Done" "Here"))) (defvar ac-source-mysource2 '((init . mysource2-init) (candidates . mysource2-cache)))
In this example,
mysource2-init function does huge processing, and stores the result into
mysource2-cache variable. Then specifying the variable in
candidates property, this source prevents huge processing on every time update completions. There are possible usage:
- Open buffers first of all
Caching strategy is important for
auto-complete-mode. There are two major ways:
init property and
cache property that is described in this section. Specifying
cache property in source definition, a result of evaluation of
candidates property will be cached and reused the result as the result of evaluation of
candidates property next time.
Rewrite the example in previous section by using
(defun mysource2-candidates () '("Huge" "Processing" "Is" "Done" "Here")) (defvar ac-source-mysource2 '((candidates . mysource2-candidates) (cache)))
There is no performance problem because this source has
cache property even if
candidates property will do huge processing.
9.4.1. Cache Expiration
It is possible to keep among more wider scope than
init property and
cache property. It may be useful for remembering all function names which is rarely changed. In these cases, how can we clear cache property not at the expense of performance? This is true time use that functionality.
ac-clear-variable-after-save to clear cache every time a buffer saved. Here is an example:
(defvar mysource3-cache nil) (ac-clear-variable-after-save 'mysource3-cache) (defun mysource3-candidates () (or mysource3-cache (setq mysource3-cache (list (format "Time %s" (current-time-string)))))) (defvar ac-source-mysource3 '((candidates . mysource3-candidates)))
Add this source to
ac-sources and complete with "Time". You may see a time when completion has been started. After that, you also see the same time, because
mysource3-candidates returns the cache as much as possible. Then, save the buffer once and complete with "Time" again. In this time, you may find a new time. An essence of this source is to use
ac-clear-variable-after-save to manage a variable for cache.
It is also possible to clear cache periodically. Use
ac-clear-variable-every-minute to do that. A way to use is same to
ac-clear-variable-after-save except its cache will be cleared every minutes. A builtin source
ac-source-functions uses this functionality.
Complete by RET will evaluate a function or an expression specified in
action property. A builtin sources
ac-source-yasnippet use this property.
9.6. Omni Completion
Omni Completion is a type of completion which regards of a context of editing. A file name completion which completes with slashed detected and a member name completion in C/C++ with dots detected are omni completions. To make a source support for omni completion, use
prefix property. A result of evaluation of
prefix property must be a beginning point of completion target string. Retuning
nil means the source is disabled within the context.
Consider a source that completes mail addresses only after "To: ". First of all, define a mail address completion source as same as above.
(defvar ac-source-to-mailaddr '((candidates . (list "firstname.lastname@example.org" "email@example.com" "firstname.lastname@example.org")))) (setq ac-sources '(ac-source-to-mailaddr))
Then enable completions only after "To: " by using
prefix property must be one of:
Specifying a regexp,
auto-complete-mode thinks of a point of start of group 1 or group 0 as a beginning point of completion target string by doing
re-search-backward with the regexp. If you want to do more complicated, use a function or an expression instead. The beginning point that is evaluated here will be stored into
ac-point. In above example, regexp is enough.
A reason why capturing group 1 is skipping "To: ". By adding this into the source definition, the source looks like:
(defvar ac-source-to-mailaddr '((candidates . (list "email@example.com" "firstname.lastname@example.org" "email@example.com")) (prefix . "^To: \\(.*\\)")))
Add this source to
ac-sources and then type "To: ". You will be able to complete mail addresses.
You may use an utility macro called
ac-define-source which defines a source and a command.
(ac-define-source mysource3 '((candidates . (list "Foo" "Bar" "Baz"))))
This expression will be expanded like:
(defvar ac-source-mysource3 '((candidates . (list "Foo" "Bar" "Baz")))) (defun ac-complete-mysource3 () (interactive) (auto-complete '(ac-source-mysource3)))
A source will be defined as usual and in addition a command that completes with the source will be defined. Calling
auto-complete without arguments will use
ac-sources as default sources and with arguments will use the arguments as default sources. Considering compatibility, it is difficult to answer which you should use
ac-define-source. Builtin sources are defined with
ac-define-sources, so you can use them alone by binding some key to these commands such like
ac-complete-filename. See also [this tips](#Completionwithspecific_source].
9.8. Source Properties
Specify a function or an expression that is evaluated only once when completion is started.
Specify a function, an expression, or a variable to calculate candidates. Candidates should be a list of string. If
cache property is enabled, this property will be ignored twice or later.
Specify a regexp, a function, or an expression to find a point of completion target string for omni completion. This source will be ignored when
nil returned. If a regexp is specified, a start point of group 1 or group 2 will be used as a value.
Specify a required number of characters of completion target string. If nothing is specified,
Specify a function or an expression that is executed on completion by RET.
Specify a limit of candidates. It overrides
Specify a symbol of candidate meaning in one character string. The symbol will be any character, but you should follow the rule:
Specify a summary of candidate in string. It should be used for summarizing the candidate in short string.
Specify an integer or
nil. This source will be ignored when the integer value is lager than a length of completion target string.
nil means nothing ignored.
Specify a face of candidate. It overrides
Specify a face of selection. It overrides
Specify a list of features (which are
required) that the source is depending.
Specify a function or an expression that describe the source is available or not.
Here is a list of often used variables.
A buffer where completion started.
A start point of completion target string.
A string of completion target.
A list of candidates.
10. Trouble Shooting
10.1. Response Latency
To keep much responsibility is very important for
auto-complete-mode. However it is well known fact that a performance is a trade off of functionalities. List up options related to the performance.
For a larger number, it reduces a cost of generating completion candidates. Or you can remove the cost by setting
nil and you can use when you truly need. See not to complete automatically for more details.
For a larger number, it reduces a cost of starting completion.
For a larger number, it reduces a displaying cost of completion menu.
For a property number, it reduces much computation of generating candidates.
10.2. Completion menu is disrupted
There is two major cases.
10.2.1. Column Computation Case
auto-complete-mode tries to reduce a cost of computation of columns to show completion menu correctly by using a optimized function at the expense of accuracy. However, it probably causes a menu to be disrupted. Not to use the optimized function, evaluate the following code:
(setq popup-use-optimized-column-computation nil)
10.2.2. Font Case
We don't good answers now, but you may shot the troubles by changing font size with
set-face-font. For instance, completion menu may be disrupted when displaying the menu including Japanese in NTEmacs. In such case, it is worth to try to evaluate the following code to fix it:
(set-face-font 'ac-candidate-face "MS Gothic 11") (set-face-font 'ac-selection-face "MS Gothic 11")
11. Known Bugs
11.1. Auto completion will not be started in a buffer
A way of delaying processes of
flyspell-mode disables auto completion. You can avoid this problem by
M-x ac-flyspell-workaround. You can write the following code into your
12. Reporting Bugs
Visit Auto Complete Mode Bug Tracking System and create a new ticket.
re-search-backwardwith the added adding
28d397e87306b8631f3ed80d858d35f0=at the end ↩